CMakeLists.txt

set(CMAKE_LEGACY_CYGWIN_WIN32 0)
cmake_minimum_required(VERSION 2.8.12 FATAL_ERROR)
project(AMDiS)

set(AMDiS_VERSION "1.2.0")

set(BASE_DIR ${AMDiS_SOURCE_DIR})
set(SOURCE_DIR ${BASE_DIR}/src)

if (NOT CMAKE_BUILD_TYPE)
  set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
      "Choose the type of build, options are: None Debug Release [RelWithDebInfo] MinSizeRel."
      FORCE)
endif ()

# ------------------------------------------------------------------------------

# some options to control the build process
option(ENABLE_PARALLEL_DOMAIN "Use parallel domain decomposition"     false)
option(ENABLE_MPI             "Compile with MPI compiler and library" false)
option(ENABLE_UMFPACK         "Enable support for the UMFPACK solver" true)
option(ENABLE_EXTENSIONS      "Use extensions for AMDiS"              false)
option(ENABLE_HYPRE           "Use HYPRE AMG solver"                  false)
option(ENABLE_PNG             "Use png reader/writer"                 false)

include(CMakeDependentOption)
# additional options for parallel_domain
# {
cmake_dependent_option(ENABLE_ZOLTAN
  "Add support for the Parallel Partitioning suite Zoltan" false
  "ENABLE_PARALLEL_DOMAIN" false)

cmake_dependent_option(ENABLE_PARALLEL_SOLVERS
  "Add some problem dependent solver, e.g. Feti, Navier-Stokes and Cahn-Hilliard" true
  "ENABLE_PARALLEL_DOMAIN" false)

cmake_dependent_option(ENABLE_BDDCML
  "Add support for the BDDCML library" false
  "ENABLE_PARALLEL_DOMAIN" false)
# }


# enable/disable some more features
option(ENABLE_COMPRESSION "Use output compression for vtu and arh files" true)
mark_as_advanced(ENABLE_COMPRESSION)

option(ENABLE_REINIT "Compile reinit library" true)
mark_as_advanced(ENABLE_REINIT)

option(ENABLE_COMPOSITE_FEM "Compile compositeFEM library" true)
mark_as_advanced(ENABLE_COMPOSITE_FEM)

option(ENABLE_OPENMP "Compile with OpenMP flags. (Experimental)" false)
mark_as_advanced(ENABLE_OPENMP)

option(ENABLE_SEQ_PETSC "Use sequential PETSc solvers" false)
mark_as_advanced(ENABLE_SEQ_PETSC)

option(BUILD_SHARED_LIBS "Build all libraries as shared or static, default: shared" true)
mark_as_advanced(BUILD_SHARED_LIBS)

if (MSVC)
  set(BUILD_SHARED_LIBS false)
  mark_as_advanced(BUILD_SHARED_LIBS)
  message(WARNING "Currently we can only build static libraries with Visual Studio")

  add_definitions(-DNOMINMAX -D_CONSOLE -DSTRICT -D_SCL_SECURE_NO_WARNINGS -D_CRT_SECURE_NO_WARNINGS)
endif (MSVC)

# parallel of sequential version
if (ENABLE_PARALLEL_DOMAIN)
  set(ENABLE_MPI CACHE BOOL "Compile with MPI compiler and library" FORCE)
  set(POSTFIX "-p")
else ()
  set(POSTFIX "-s")
endif ()

# ------------------------------------------------------------------------------

if (${CMAKE_VERSION} VERSION_LESS "3.2")
  # Fallback to classical CMakeLists file
  include(${AMDiS_SOURCE_DIR}/cmake/CMakeLists.txt)
else ()
  include(${AMDiS_SOURCE_DIR}/cmake3/CMakeLists.txt)
endif ()

# ------------------------------------------------------------------------------

include(CMakePackageConfigHelpers)
write_basic_package_version_file(
  ${AMDiS_BINARY_DIR}/AMDISConfigVersion.cmake
  VERSION ${AMDiS_VERSION}
  COMPATIBILITY SameMajorVersion
)
install(FILES ${AMDiS_BINARY_DIR}/AMDISConfigVersion.cmake DESTINATION share/amdis/)