target_enable_umfpack.cmake

macro(target_enable_umfpack _TARGET_ _SCOPE_)
    if (${ARGC} GREATER 2)
      set(LINK_EXECUTABLE ON)
    else ()
      set(LINK_EXECUTABLE OFF)
    endif ()

    if (WIN32)
        set(SuiteSparse_USE_LAPACK_BLAS ON)
    endif (WIN32)

    if (SuiteSparse_DIR)
       file(TO_CMAKE_PATH ${SuiteSparse_DIR} SuiteSparse_DIR)
    endif (SuiteSparse_DIR)

    # try to use a cmake-package of suitesparse
    find_package(SuiteSparse QUIET HINTS ${AMDIS_SuiteSparse_DIR})
    if (SuiteSparse_FOUND)
        message(STATUS "Found SuiteSparse CMake-library")
        include(${USE_SuiteSparse})
        if (LINK_EXECUTABLE OR APPLE)
          target_link_libraries(${_TARGET_} ${_SCOPE_} ${SuiteSparse_LIBRARIES})
        endif (LINK_EXECUTABLE OR APPLE)
        target_include_directories(${_TARGET_} ${_SCOPE_} ${SuiteSparse_INCLUDE_DIR} ${SuiteSparse_METIS_INCLUDE_DIR})
        set(FOUND_SUITESPARSE_LIBS ${SuiteSparse_LIBRARIES})
    else (SuiteSparse_FOUND)
        # find umfpack manually by searching for umfpack.h header file
        find_library(UMFPACK_LIBRARY umfpack
          HINTS ${AMDIS_UMFPACK_ROOT_DIR}
          PATHS $ENV{EBROOTSUITESPARSE}
          PATH_SUFFIXES lib/ lib64/
	        DOC "Library file for UMFPACK")
        find_file(UMFPACK_H umfpack.h
          HINTS ${AMDIS_UMFPACK_ROOT_DIR}/include
          PATHS /usr/include/suitesparse /usr/include/ufsparse $ENV{EBROOTSUITESPARSE}/include
	        DOC "Headerfile umfpack.h for UMFPACK")

        if (UMFPACK_H AND UMFPACK_LIBRARY)
            get_filename_component(UMFPACK_PATH ${UMFPACK_H} PATH)
            target_include_directories(${_TARGET_} ${_SCOPE_} ${UMFPACK_PATH})

            get_filename_component(UMFPACK_LIB_PATH ${UMFPACK_LIBRARY} PATH)
            set(FOUND_SUITESPARSE_LIBS ${UMFPACK_LIBRARY})

            # extract root directory from umfpack lib dir
            set (UMFPACK_ROOT_DIR ${UMFPACK_LIB_PATH}/..)
            if (NOT EXISTS ${UMFPACK_ROOT_DIR}/include)
              message(WARNING "directory ${UMFPACK_ROOT_DIR} is not a valid root dir of an umfpack installation.")
            endif ()

            if (LINK_EXECUTABLE OR APPLE)

              # find all connected libraries
              find_library(AMD_LIBRARY amd HINTS ${UMFPACK_LIB_PATH})

              find_library(BLAS_LIB
                NAMES blas fblas openblas
                HINTS ${BLAS_DIR}/lib ${UMFPACK_LIB_PATH} /usr/lib/openblas-base /usr/lib/atlas-base)
              if (BLAS_LIB)
                set(BLAS_LIBRARIES ${BLAS_LIB})
              else (BLAS_LIB)
                find_package(BLAS REQUIRED)
              endif (BLAS_LIB)

              find_library(CHOLMOD_LIBRARY cholmod HINTS ${UMFPACK_LIB_PATH})
              find_library(COLAMD_LIBRARY colamd HINTS ${UMFPACK_LIB_PATH})
              find_library(SUITESPARSECONFIG_LIBRARY suitesparseconfig HINTS ${UMFPACK_LIB_PATH})
              if (AMD_LIBRARY AND BLAS_LIBRARIES)
                  list(APPEND FOUND_SUITESPARSE_LIBS ${AMD_LIBRARY} ${BLAS_LIBRARIES})
              endif (AMD_LIBRARY AND BLAS_LIBRARIES)
              if (CHOLMOD_LIBRARY)
                  list(APPEND FOUND_SUITESPARSE_LIBS ${CHOLMOD_LIBRARY})
              endif (CHOLMOD_LIBRARY)
              if (COLAMD_LIBRARY)
                  list(APPEND FOUND_SUITESPARSE_LIBS ${COLAMD_LIBRARY})
              endif (COLAMD_LIBRARY)
              if (SUITESPARSECONFIG_LIBRARY)
                  list(APPEND FOUND_SUITESPARSE_LIBS ${SUITESPARSECONFIG_LIBRARY})
              endif (SUITESPARSECONFIG_LIBRARY)

              target_link_libraries(${_TARGET_} ${_SCOPE_} ${FOUND_SUITESPARSE_LIBS})
            endif (LINK_EXECUTABLE OR APPLE)
        else()
            if (NOT UMFPACK_H)
              message(FATAL_ERROR "Could not find the UMFPACK header umfpack.h.")
            endif ()
            if (NOT UMFPACK_LIBRARY)
              message(FATAL_ERROR "Could not find the UMFPACK library libumfpack.so")
            endif ()
        endif (UMFPACK_H AND UMFPACK_LIBRARY)
    endif (SuiteSparse_FOUND)


    # Check for clock_gettime in librt
    if (NOT WIN32 AND (LINK_EXECUTABLE OR APPLE))
      include(CheckLibraryExists)
      check_library_exists(rt clock_gettime "time.h" HAVE_CLOCK_GETTIME)
      if (HAVE_CLOCK_GETTIME)
          target_link_libraries(${_TARGET_} ${_SCOPE_} rt)
      else ()
          check_library_exists(c clock_gettime "" HAVE_CLOCK_GETTIME)
      endif (HAVE_CLOCK_GETTIME)
    endif (NOT WIN32 AND (LINK_EXECUTABLE OR APPLE))


    # collect informations about umfpack version and found libraries
    if (FOUND_SUITESPARSE_LIBS)
        find_file(_UMFPACK_H umfpack.h PATHS ${SuiteSparse_INCLUDE_DIR} ${UMFPACK_PATH} NO_DEFAULT_PATH)
        file(STRINGS ${_UMFPACK_H} UMFPACK_VERSION_LINE REGEX "#define UMFPACK_VERSION")
        string(REGEX MATCH "\"UMFPACK V?([^\"]+)\"" UMFPACK_VERSION_REGEX ${UMFPACK_VERSION_LINE})
        set(UMFPACK_VERSION ${CMAKE_MATCH_1})
        unset(_UMFPACK_H CACHE)

        message(STATUS "UMFPACK version: ${UMFPACK_VERSION}")
        if (LINK_EXECUTABLE OR APPLE)
          message(STATUS "Found the following SuiteSparse libraries:")
          foreach (lib ${FOUND_SUITESPARSE_LIBS})
              message(STATUS "  ${lib}")
          endforeach ()
        endif (LINK_EXECUTABLE OR APPLE)
    endif (FOUND_SUITESPARSE_LIBS)

    target_compile_definitions(${_TARGET_} ${_SCOPE_}
        HAVE_UMFPACK=1
        MTL_HAS_UMFPACK=1)

endmacro(target_enable_umfpack)